¡Macros!: Todo lo que necesitas saber para comenzar a crear tus propios macros.

[IvoryDesert]

¿Tu hermandad te pide que hagas macros pero no sabes cómo?¿El macro que quieres hacer no funciona y no sabes por qué?¿Aburrido a las 3 de la mañana y estas revisando el foro?

Esta guía es para ti. y tocara temas cómo: ¿Qué es un macro?, ¿Cómo hacer un macro?, ¿Qué puede hacer un macro? y más!

 

---

¿Qué es un macro?

 

Un macro es una secuencia de instrucciones, como castear una habilidad o usar un objeto, que se ejecutan de forma consecutiva al presionar un botón. pero un macro no puede hacer todo por ti y es importante tener en cuenta los siguientes puntos antes de continuar:

• Puedes tener un máximo de 36 macros generales que se comparten entre personajes y 18 macros ligados a un solo personaje.
• Un macro solo puede tener un máximo de 255 caracteres.
• Un macro NO se puede pausar.
• Un macro NO puede revisar si tienes un buff/debuff o no.
• Un macro NO puede revisar si tienes mana/energía/ira/poder rúnico/enfoque(mascota) o no.
• Un macro NO puede revisar si tu hechizo está en cooldown o no.
• Un macro NO puede revisar si tienes aprendido el hechizo que deseas ocupar ni puede revisar si el objeto que intentas ocupar esta en tu bolsa.

Teniendo esto en mente.

 

¿Como hacer un macro?

 

Primero debes abrir la interfaz de macros y existen 2 formas de hacer esto:

1. Ingresar /m o /macro en el chat ingame.
2. Hacer clic en ESC y luego presionar el botón “Macros”.

Una vez dentro de la interfaz selecciona la pestaña que deseas (macros generales o macros de personaje) y haz clic en “Nuevo”.

Al crear un nuevo macro lo primero que debes de hacer es darle un nombre y luego escoger un icono. (el primer icono, el símbolo de interrogación, hace que el macro seleccione un icono de forma automática dependiendo de qué hechizo,habilidad o ítem se esté utilizando).

Una vez hayamos hecho esto podremos finalmente comenzar a escribir nuestro macro y una vez hayamos finalizado podemos arrastrar el icono de la macro a nuestra barra de la misma manera en la que se puede arrastrar una habilidad del libro de hechizos.

 

¿En qué consiste un macro? y Sintaxis de un macro

 

En un principio, un macro puede parecer algo complicado de hacer, pero cuando es visto de cerca es algo bastante sencillo.

Para que un macro funcione correctamente este, generalmente, requiere de 3 partes:

• Uno o más comandos el cual SIEMPRE inicia con un “/”.
• Una o más condiciones SIEMPRE dentro de corchetes “[]”.
• Y uno o más objetos (habilidades, hechizos o ítems).
• ¡OJO!. Puesto que no todos los comandos necesitan una condición o un objeto para funcionar como veremos mas adelante.

 

/comando [condición] objeto

 

Algunos puntos importantes son los siguientes:

• Cada comando requiere su propia linea dentro del macro.
• Si hay más de una condición, estos tienen que estar separados con ",".
• Cada condición debe cumplirse para lanzar su objeto asociado.
• Si quieres utilizar más de un objeto con un solo comando, estos tienen que estar separados con ";".
• Una vez se cumplan las condiciones de activación, tu macro lanzará ese hechizo asociado, sin importar que condiciones se encuentren después.
• TODAS las condiciones asociadas con un objeto deben de cumplirse para que el objeto sea lanzado.
• Puedes colocar un hechizo o habilidad directamente desde tu libro de hechizos, sin necesidad de escribirlo a mano, utilizando SHIFT mientras haces clic sobre el hechizo. Si tu objeto es un ítem puedes hacer lo mismo desde tus bolsas o desde tu pestaña de personaje.
• Si tu objeto es un hechizo o habilidad con rango, puedes utilizar el rango de hechizo que quieras colocando, entre paréntesis, el rango deseado al final del hechizo.
• Si tu objeto es un hechizo o habilidad con más de un rango, solo colocar el nombre del hechizo hace que se lance automáticamente el MAYOR rango que tengas aprendido de dicho hechizo, otra forma de hacer esto es agregar "()" al final de tu hechizo.
• Un macro SIEMPRE se ejecuta de arriba hacia abajo y de izquierda a derecha.
• Debido a lo anterior, recuerda NO separar tus condiciones puesto que esto puede causar problemas con tu macro.

 

/comando [condición 1,condición 2] objeto A;[condición 3] objeto B
/comando [condición 4] objeto C

 

Por lo tanto, al ejecutar este macro pasara lo siguiente:

• Si se cumplen las condiciones 1, 2 y 4, se lanzará objeto A y luego objeto C.
• Si se cumplen las condiciones 3 y 4, se lanzará el objeto B y luego el objeto C.
• Si solo se cumple la condición 4 solo objeto C sera lanzado.
• Si ninguna condición se cumple el macro no hará nada.

 

¡Simple!,¡Sencillo!, pero, debemos recordar que un macro no revisa si tus hechizos están en CD, por ende, si tu primer comando contiene algún objeto que cause GCD el macro nunca lanzará el objeto C.

 

---

Lista de Comandos

 

Comandos de objeto:

 

/cast - Lanza el objeto seleccionado. Este es el comando mas utilizado al momento de hacer un macro.

/cast [condición] objeto

 

/castrandom - Lanza de forma aleatoria uno de los objetos seleccionados. Para usar este comando correctamente cada objeto debe estar separado con una ",".

/castrandom [condición] objeto1,objeto2,objeto3

 

/castsequence - Lanza de forma secuencial los objetos seleccionados.

/castsequence [condición] objeto1, objeto2, objeto3
/castsequence [condición] reset=# objeto1, objeto2, objeto3

Este comando es algo peculiar. Ya que puedes añadir una condición especial llamada "reset" para cambiar su funcionamiento.

En el ejemplo de mas arriba, se pueden apreciar dos formas de ocupar el comando:

1. En la primera forma, cada ves que utilicemos el macro se lanzara una habilidad, hechizo o ítem diferentes, siguiendo la secuencia que nosotros escribimos y al llegar al final de la secuencia volveremos al inicio.
2. En la segunda forma añadimos la condición "reset" a nuestro macro, esta condición especial nos permite regresar al inicio de nuestra secuencia dependiendo de que sub-condición hayamos usado:

• Reemplazar # por un número hará que nuestra secuencia se reinicie luego de que pase esa cantidad de segundos (2=2segundos, 45=45segundos, etc...).
• Reemplazar # por "target" hará que nuestra secuencia se reinicie cuando cambiemos de objetivo.
• Reemplazar # por "combat" hará que nuestra secuencia se reinicie cuando dejemos el combate.
• Reemplazar # por SHIFT, ALT o CTRL hará que nuestra secuencia se reinicie cuando ejecutemos el macro presionando la tecla correspondiente.

 

/stopcasting - Intentara cancelar el objeto que se esté casteando. Este es un comando importante y es usado a menudo en conjunto con hechizos defensivos.

/stopcasting [condición]

 

/use - Utiliza el objeto seleccionado. Este es un comando sumamente versátil con sus propias reglas a seguir.

/use [condición] NombreDeObjeto
/use [condición] NumeroDeSlotDePersonaje
/use [condición] NumeroDeBolsa NumeroDeSlotEnLaBolsa

Lo que hace este comando es muy similar a hacer click derecho sobre el objeto seleccionado, es decir:

• En el primer ejemplo, se utiliza el ítem directamente: si es un consumible se utilizará, si es un ítem equipable se equipará en el slot de personaje correspondiente y si es un ítem ya equipado se activara la habilidad de ese ítem.
• En el segundo ejemplo se utilizara la habilidad del ítem equipado en el slot de personaje seleccionado.
• En el tercer ejemplo se utilizará directamente el ítem en la posición seleccionada.

 

╔═══╦═══╦═══╦═══╦═══╗

║   0   ║    1   ║   2   ║   3   ║   4   ║  →  0 es siempre la mochila y el llavero no posee número

╚═══╩═══╩═══╩═══╩═══╝

╔═══╦═══╦═══╦═══╦═══╗

║   1   ║    2   ║   3   ║   4   ║   5   ║

╠═══╬═══╬═══╬═══╬═══╣  →  siempre comienza en 1 y el limite es el tamaño de la bolsa

║   6   ║   7   ║    8   ║   9   ║  etc  ║

╚═══╩═══╩═══╩═══╩═══╝

 

/userandom - Utiliza los ítems seleccionados de forma aleatoria. Similar en uso al comando /castrandom pero sigue las mismas reglas que el comando /use.

/userandom [condición] objeto1, objeto2, objeto3

 

/equip - Equipa el ítem seleccionado en el slot correspondiente.

/equip [condición] objeto

 

/equipslot # - Equipa el ítem seleccionado en el slot de personaje indicado. Utilizado de forma similar al comando equip, pero la diferencia radica en que tú escoges en que slot quieres colocar el ítem. Para ocuparlo correctamente debes reemplazar # con el NÚMERO del slot que quieres equipar.

/equipslot [condición] # objeto

Lista de slots de personaje:

┌──────────────────┐   0 = Munición    10 = Manos

│[ 1 ]╔═══════════╗[10] │   1 = Cabeza      11 = Dedo 1
│[ 2 ]║                               ║[ 6 ] │   2 = Cuello         12 = Dedo 2
│[ 3 ]║                               ║[ 7 ] │   3 = Hombro      13 = Abalorio 1
│[15]║        Personaje        ║[ 8 ] │   4 = Camisa       14 = Abalorio 2
│[ 5 ]║                               ║[11] │   5 = Pecho          15 = Espalda
│[ 4 ]║                               ║[12] │   6 = Cintura        16 = Mano Derecha
│[19]║                               ║[13] │   7 = Piernas        17 = Mano Izquierda
│[ 9 ]╚═══════════╝[14] │   8 = Pies             18 = A distancia/Reliquia
│██ [ 16 ][ 17 ][ 18 ]←[ 0 ] ██ │   9 = Muñeca       19 = Tabardo
└──────────────────┘ 

 

/equipset - Se utiliza en conjunto con el gestor de equipamiento.

/equipset [condición] NombreDelConjunto

 

Comandos de acción:

 

/cancelaura - Cancela el aura o buffo seleccionado.

/cancelaura [condición] NombreDelAura

 

/cancelform - Este comando cancela la forma actual para volver a la normalidad.

/cancelform [condición]

Es importante saber que las actitudes del Guerrero NO se pueden cancelar, siempre hay una activa.

 

/startattack - Comienza el ataque.

/startattack [condición]

/stopattack - Detiene el ataque.

/stopattack [condición]

/stopmacro - Detiene el macro.

/stopmacro [condición]

 

 

Comandos de objetivo:

 

/assist - Asiste al objetivo actual.

/assist [condición]

/focus - Estableces un foco.

/focus [condición]

/clearfocus - Quitas tu foco actual.

/clearfocus [condición]

/target - Estableces un objetivo.

/target [condición] Nombre

Este comando es algo especial, en el sentido que no necesitas el nombre exacto del objetivo para seleccionarlo.

Por ejemplo:

/target Sol 

Seleccionará como objetivo a "Sol", pero si no hay nadie llamado Sol cerca de ti, el macro seleccionara la unidad con un nombre similar más cercano a ti. esto quiere decir que si hay algún mob llamado Soldado este será tu nuevo objetivo.

/cleartarget - Quita tu objetivo actual.

/cleartarget [condición]

/targetexact - Estableces un objetivo exacto.

/targectexact [condición] NombreExactoDelObjetivo

Utilizando el ejemplo anterior, si colocas "Sol", este comando solo pondrá como objetivo a "Sol" y nadie mas.

 

/targetlastenemy - Seleccionas nuevamente al ULTIMO enemigo seleccionado.

/targetlastenemy [condición]

 

/targetlastfriend - Seleccionas nuevamente al ULTIMO aliado seleccionado.

/targetlastfriend [condición]

/targetlasttarget - Seleccionas nuevamente a tu ULTIMO objetivo.

/targetlasttarget [condición]

 

Comandos de ciclo:

 

Todos los comandos de ciclo pueden ser usados de dos formas diferentes dependiendo de si añades un "1" al comando o no. reemplazar # por un 1en estos comandos hará que ciclen de forma inversa.

 

/targetenemy # - Ciclas al siguiente objetivo enemigo de forma similar al apretar TAB.

/targetenemy [condición]

/targetenemyplayer # - Ciclas al siguiente jugador enemigo.
 

/targetenemyplayer [condición]

/targetfriend #  - Ciclas al siguiente objetivo aliado.

/targetfriend [condición]

/targetfriendplayer # - Ciclas al siguiente jugador aliado.
 

/targetfriendplayer [condición]

/targetparty # - Ciclas al siguiente jugador dentro de tu party.

/targetparty [condición]

/targetraid # - Ciclas al siguiente jugador dentro de tu raid.

/targetraid [condición]

 

Comandos de mascota:

 

/petaggresive - Vuelve a tu mascota agresiva.

/petagressive [condición]

/petdefensive - Vuelve a tu mascota defensiva.

/petdefensive [condición]

/petpasive - Vuelve a tu mascota pasiva.

/petpasive [condición]

/petattack - Ordena a tu mascota a atacar.

/petattack [condición]

/petfollow - Ordena a tu mascota a seguirte.

/petfollow [condición]

/petstay - Ordena a tu mascota a que se quede quieta.

/petstay [condición]

/petautocaston - Hace que la habilidad de mascota seleccionada comience a ser casteada de forma automática.

/petautocaston [condición] NombreDeHabilidadDeMascota

/petautocastoff - Hace que la habilidad de mascota seleccionada deje de ser casteada de forma automática.

/petautocastoff [condición] NombreDeHabilidadDeMascota

/petautocasttoggle - Hace que la habilidad de mascota seleccionada cambie de normal a automático y viceversa.

/petautocasttoggle [condición] NombreDeHabilidadDeMascota

 

¡OJO! para que los comandos /petautocast funcionen correctamente asegurate que la habilidad que quieras ocupar puede ser casteada de forma automática. Para esto, revisa las esquinas en las habilidades de tu mascota, si estas tienen borde dorado entonces es una habilidad con modalidad automática

 

Comandos varios:

 

/click - Simula un click de mouse en el botón seleccionado.

/click [condición] NombreDeBarra#

 

Para poder utilizar el comando click debes de colocar el nombre de la barra y el numero de ranura de esa barra sobre la que simularas tu clic. Los nombres de las barras son los siguientes:
 

ActionButton# = Barra principal.
BonusActionButton# = Barra dinámica. Esta es la barra que aparece cuando cambias de forma con el Druida, cambias de actitud con el Guerrero, entras en sigilo con el Pícaro, Etc...
MultiBarBottomLeftButton# = Barra extra abajo a la izquierda.
MultiBarBottomRightButton# = Barra extra abajo a la derecha.
MultiBarRightButton# = Barra extra de la derecha.
MultiBarLeftButton# = Barra extra que aparece al lado izquierdo de la barra extra de la derecha.
PetActionButton# = Barra de mascota.
ShapeshiftButton# = Barra de Forma/Actitud/Auras/Etc.

¡OJO! Deberás de reemplazar # por el número de ranura que deseas ocupar.

 

/changeactionbar # - Cambia a la barra seleccionada (reemplaza # por el numero de la barra que deseas ver).

/changeactionbar # [condición]

/swapactionbar # ## - Intercambia las barras seleccionadas (reemplaza # y ## con los números de las barras que quieres intercambiar).

/swapactionbar # ## [condición]

/dismount - Te desmonta.

/dismount [condición]

/usetalents # - Este comando solo es utilizable si tienes una segunda página de talentos (reemplaza # por 1 o 2 según corresponda).

/usetalents # [condición]

 

 

---

Condiciones:

 

Cuando añades una condición a tu macro cambias su comportamiento. De esta forma puedes hacer que tu macro haga una acción u otra dependiendo de las condiciones que posea.

 

¡OJO! Antes de continuar:

 

• Debes de recordar que las condiciones y los objetos son opcionales, por ende, si deseas que tu macro no posea ninguna condición puedes colocar solo los "[]" o puedes dejar el espacio de condición en blanco.

 

Ejemplo:

 

/cast [] Descarga de escarcha()

 

Es lo mismo qué:

 

/cast Descarga de escarcha()

 

• Colocar un "no" antes de una condición implica lo CONTRARIO

 

Ejemplo:

 

/cast [dead] Resurrección(); [nodead] Luz Sagrada()

 

En este macro se utiliza la condición "dead", que verifica si el objetivo esta muerto, para castear el hechizo resurrección y también utiliza su contraparte "nodead", que verifica si NO esta muerto, para lanzar el hechizo luz sagrada.

 

• Comandos que contengan ":" en ellos pueden permitir más de una sub-condición, para esto, debes separar cada sub-condición con "/"

 

Ejemplo:

 

/cast [noform][form:2/4]Fuego feérico;[form:1/3]Fuego feérico (feral)

 

En este macro, la condición "form" admite mas de un parámetro, lo que permite castear fuego feérico mientras se esta normal y en las formas de viaje mientras que en forma de oso y gato lanzara el hechizo feral.

 

Lista de Condiciones:

 

actionbar:# - Si la barra seleccionada es tu barra actual (reemplaza # con el número de barra que quieres seleccionar).

/comando [actionbar:#] objeto

button:# o btn:# - Si el macro es activado presionando el botón del mouse seleccionado (reemplaza # con el número de botón de tu ratón. 1 es el botón izquierdo, 2 el derecho, 3 el de la rueda, el botón 4 en Adelante depende de tu mouse).

/comando [button:#] objeto

/comando [btn:#] objeto

channeling o channeling:{nombre del hechizo} - Si estas canalizando cualquier hechizo o algún hechizo especifico.

/comando [channeling] objeto

/comando [channeling:NombreDeObjeto] objeto

¡OJO! castear y canalizar un hechizo son acciones DIFERENTES. Revisa tu libro de hechizos para saber que hechizo se canaliza o no.

combat - Si te encuentras en combate.

/comando [combat] objeto

dead - Si tu objetivo está muerto.

/comando [dead] objeto

equipped:# o worn:# - Si el ítem seleccionado se encuentra equipado. esta condición es un caso especial con muchas variantes.

/comando [equipped:#] objeto

/comando [worn:#] objeto

Para un correcto uso de esta condición debes reemplazar # con uno de los siguientes parametros:

 

armadura/tela/cuero/malla/placas/reliquia/tótem/ídolo/tratado/sigilo/bolsa/SlotDePersonaje/arma/dos manos/una mano/mano derecha/mano izquierda/sostener con la mano izquierda/a distancia/arco/ballesta/arma de fuego/varita/arrojadizas/espada/espada de una mano/espada de dos manos/hacha/hacha de una mano/hacha de dos manos/maza/maza de una mano/maza de dos manos/bastón/arma de asta/caña de pescar/daga/arma de puño/escudo

exists - Si el objetivo existe. Varias condiciones indican de forma implícita que el objeto existe. Por ejemplo, dead, harm y help implican que existe un objetivo.

/comando [exists] objeto

flyable - Si es POSIBLE volar en la zona en la que estas. ¡OJO! puesto que NO verifica si PUEDES volar.

/comando [flyable] objeto

flying - Si te encuentras volando ,ya sea con montura o con forma de vuelo.

/comando [flying] objeto

group:# si te encuentras en un grupo. Debes reemplazar # con party o raid según corresponda.

/comando [group:party] objeto

/comando [group:raid] objeto

harm - Si es posible dañar al objetivo con habilidades, hechizos o Ítems.

/comando [harm] objeto

help - si es posible sanar al objetivo con habilidades, hechizos o Ítems.

/comando [help] objeto

indoors - Verifica si te encuentras en interiores.

/comando [indoors] objeto

modifier:# o mod:# - Verifica si te encuentras presionando el modificador al momento de lanzar el objeto. Para utilizar esta condicion correctamente debes borrar #, para indicar cualquier modificador, o reemplaza # con CTRL, ALT y/o SHIFT.

/comando [mod] objeto

/comando [modifier:shift] objeto

/comando [mod:ctrl/alt] objeto

mounted - Si estas en una montura.

/comando [mounted] objeto

outdoors - Si estas en exteriores.

/comando [outdoors] objeto

pet o pet:{nombre o tipo de mascota} - Si tienes una mascota activa o si la mascota especificada esta activa.

/comando [pet] objeto

/comando [pet:NombreDeTuMascota] objeto

/comando [pet:RazaDeTuMascota] objeto

raid - Si tu objetivo está en tu raid.

/comando [raid] objeto

spec:# - Si te encuentras utilizando la página de talentos seleccionada. reemplaza # con 1 o 2 según corresponda.

/comando [spec:#] objeto

stance:# o form:# - Si te encuentras en la forma o actitud seleccionada. Debes reemplazar # por el numero que coincida con la forma, es decir, Guerreros tienen actitud de batalla como forma 1 y Druidas tienen forma de oso como forma 1.

/comando [form:#] objeto

 

stealth - Verifica si te encuentras en sigilo.

/comando [stealth] objeto

swimming - Si te encuentras nadando.

/comando [swimming] objeto

target=# - Es una condición especial e indica al macro cual será el objetivo de tu habilidad, hechizo o ítem.

/comando [target=#] objeto

Para que esta condición sea utilizada correctamente, se debe reemplazar # por alguno de los siguientes parámetros:

• mouseover = toma como objetivo la unidad o jugador bajo el cursor de tu mouse.
• targettarget = el objetivo de tu objetivo. Puedes seguir añadiendo “target” al final hasta hacer algo realmente ridículo como “targettargettargettargettargettargettarget”, que es lo mismo qué: “el objetivo del objetivo del objetivo del objetivo del objetivo del objetivo de tu objetivo”.
• lasttarget = el objetivo de tu hechizo, habilidad o ítem es tu objetivo anterior.
• pet = el objetivo es tu mascota.
• pettarget = el objetivo de tu hechizo, habilidad o ítem es el objetivo de tu mascota.
• focus = el objetivo es tu focus.
• party/raid# = el objetivo será el miembro de tu grupo o raid número#.
• {nombre} = el nombre de tu objetivo.
• player = tu personaje.

---

*Esta guía la cree en base a lo que he aprendido durante años y en base a lo recopilado hace años por el usuario Wildhorn en su propia guía.*

**Ante cualquier duda, comentario, reclamo o sugerencia por favor dejar un comentario.**

[Ryuzaki]

Es una excelente guía y muy útil para los que son nuevos en el mundo de las macros.

Ni yo hubiese logrado una guía tan completa.

[Silverproud]

Buenisima guia! muy completa

Importante agregar que, para ahorrar caracteres la condicion de objetivo que se define como  "target =" se puede resumir en "@" por lo tanto quedaría asi:

 

target=mouseover se resume en  @mouseover 

target=targettarget  se resumen en  @targettarget

target=focus pasa a ser @focus

 

y así sucesivamente.

[Yosoygru]

Alguien me ayuda no me funciona la macro de tirar muerte y descomposicion en donde apunto con el mause pero sin clicquear al piso

/cast[@cursor] Muerte y Descomposición(Rango 4)

 

Editado 29 de Mayo del 2023 por Yosoygru

[Silverproud]

hace 7 minutos, Yosoygru dijo:

Alguien me ayuda no me funciona la macro de tirar muerte y descomposicion en donde apunto con el mause pero sin clicquear al piso

/cast[@cursor] Muerte y Descomposición(Rango 4)

 

 

Elimina @cursor, creo que está demás, solo pone /cast Muerte y Desconposición (Rango 4) y yá.

El @cursor o @mouse se usa cuando quieres que lance el hechizo sobre "alguien" que esta bajo tu cursor. Por ejemplo, yo uso @mouse para https://wotlk.ultimowow.com/?spell=1152 de modo que puedo quitarle maldiciones a los de mi party solo colocando el mouse sobre sus nombres sin dejar de estar pegando en modo retri.

[Yosoygru]

hace 5 minutos, Silverproud dijo:

Elimina @cursor, creo que está demás, solo pone /cast Muerte y Desconposición (Rango 4) y yá.

El @cursor o @mouse se usa cuando quieres que lance el hechizo sobre "alguien" que esta bajo tu cursor. Por ejemplo, yo uso @mouse para Purificar de modo que puedo quitarle maldiciones a los de mi party solo colocando el mouse sobre sus nombres sin dejar de estar pegando en modo retri.

osea, segun consegui que hay una macro q uso la tecla y donde apunte con el raton lo tira automatico sin cliquear el piso o sobre el tarjet

 

[Silverproud]

hace 32 minutos, Yosoygru dijo:

osea, segun consegui que hay una macro q uso la tecla y donde apunte con el raton lo tira automatico sin cliquear el piso o sobre el tarjet

 

uhm... prueba cambiando @cursor por @mouse ó @mouseover

lo proble y no funciona

Editado 29 de Mayo del 2023 por Silverproud

[Silverproud]

hace 32 minutos, Yosoygru dijo:

osea, segun consegui que hay una macro q uso la tecla y donde apunte con el raton lo tira automatico sin cliquear el piso o sobre el tarjet

 

Me puse a revisar y lo que quieres esta fuera del alcance de una macro. Tendria q ser un script... y uff ese no es mi campo jaja

[thekiller]

En 28/5/2023 a las 20:53, Silverproud dijo:

Me puse a revisar y lo que quieres esta fuera del alcance de una macro. Tendria q ser un script... y uff ese no es mi campo jaja

Hola excelente guía,  me ayudas con una macro?? 

Quisiera tirar mano de libertad en una macro,  por ejemplo tirarle mano al target,  si no tengo target al foco y si no tengo nada a mi mismo . 

Se puede hacer una macro así o por lo menos al target o foco ?? 

Nota : intente hacerla pero me combulsiono el cerebro

[Silverproud]

hace 3 horas, thekiller dijo:

Hola excelente guía,  me ayudas con una macro?? 

Quisiera tirar mano de libertad en una macro,  por ejemplo tirarle mano al target,  si no tengo target al foco y si no tengo nada a mi mismo . 

Se puede hacer una macro así o por lo menos al target o foco ?? 

Nota : intente hacerla pero me combulsiono el cerebro

Hola, gracias. Pero ojo q esta guia es de @IvoryDesertno mía.

 

Respecto a lo q dices si se puede

Asumanos que quieres tirar "Mano de libertad"

 

Entonces en ese caso la macro que me indicas tendría que ser así:

/cast [@target,exists,help][@focus,exists,help][@player] mano de libertad

 

Al apretar el botón la macro primero va a verificar que tengas target y este sea amigable, si eso es asi le lanza mano, sino no es asi verifica q tengas foco y sea amigable y se lo lanza, si no hay foco o este no cumple con el requisito te lo tira a ti mismo.

 

Yo uso esta para mano de libertad:

/cast [@focus,exists,help][@mouseover,help][@player] mano de libertad

 

Aca primero se lo lanza al foco, si este no es valido verifica al amigito q tenga en mouseover (notese q el mouseover es valido tanto para el pj q esta bajo el mouse como para el marco de unidad). No lo tengo en target pq como juego en dps rara vez tengo en target un amigo.

[thekiller]

hace 23 minutos, Silverproud dijo:

Hola, gracias. Pero ojo q esta guia es de @IvoryDesertno mía.

 

Respecto a lo q dices si se puede

Asumanos que quieres tirar "Mano de libertad"

 

Entonces en ese caso la macro que me indicas tendría que ser así:

/cast [@target,exists,help][@focus,exists,help][@player] mano de libertad

 

Al apretar el botón la macro primero va a verificar que tengas target y este sea amigable, si eso es asi le lanza mano, sino no es asi verifica q tengas foco y sea amigable y se lo lanza, si no hay foco o este no cumple con el requisito te lo tira a ti mismo.

 

Yo uso esta para mano de libertad:

/cast [@focus,exists,help][@mouseover,help][@player] mano de libertad

 

Aca primero se lo lanza al foco, si este no es valido verifica al amigito q tenga en mouseover (notese q el mouseover es valido tanto para el pj q esta bajo el mouse como para el marco de unidad). No lo tengo en target pq como juego en dps rara vez tengo en target un amigo.

Muchas gracias probaré la macro , si me di cuenta q no era suya pero gracias por responder,  un saludo y un abrazo para usted y el creador de la guía.

Nota : no llgue ni a la primera mitad de su macro cuando hice el intento de la mía ajaja 

Nota 2 : se q juegas pala , par favor déjame las macros q utilizas

Nota 3 : no todos somos buenos con los pjs ( me incluyo) por eso quiero conocer y me ayudo de las macros para mejorar mi experiencia de juego , resumen soy manco y acepto la ayuda

[sirfelipee2]

Buenas a todos, tengo una pregunta, se puede hacer una macro que haga saltar al personaje?

 

[Javier123]

Hola a todos, existe algún macro para q use la habilidad solo contra enemigos q no sean jugadores ?.

[Silverproud]

En 31/12/2024 a las 16:34, Javier123 dijo:

Hola a todos, existe algún macro para q use la habilidad solo contra enemigos q no sean jugadores ?.

No se puede, no existe apropósito tal comprobación para evitar ventajas en PvP.

Quiza si eres bueno redactando script se podria ingeniar algo, pero por mi parte eso esta fuera de mi jurisdicción xd

[Pampucho]

Hola que tal, se podría hacer una macro con mouseover para cambiar de foco? De poderse como sería? No se me ocurre la forma de armarlo xd

[España]

hace 3 horas, Pampucho dijo:

se podría hacer una macro con mouseover para cambiar de foco?

Esto sirve para poner en foco a la unidad que tengas bajo el cursor /focus [@mouseover,exists]

[Djklyncan]

Hola, no encontre otro post con temas de macro y viendo que acá se puede obtener un tipo de guía, quería consultar un problema que he presentado y es que no he podido hacer que dos macros me funcionen uno es el de lanzar muerte y descomposición del DK sobre el cursor y el otro macro es sobre mi mismo, a continuación dejare los dos macro que intento usar y no consigo que funcione.
De antemano agradezco cualquier aclaración sobre que estoy haciendo mal si es tema de redacción alguna letra o algo que me ayude con estos dos macros.

Para lanzar sobre el cursor:

#showtooltip Muerte y descomposición
/cast [@cursor] Muerte y descomposición

Para lanzar sobre mi mismo:

#showtooltip Muerte y descomposición
/cast [@player] Muerte y descomposición

[Silverproud]

En 8/9/2026 a las 17:11, Djklyncan dijo:

#showtooltip Muerte y descomposición
/cast [@player] Muerte y descomposición

Hola, https://wotlk.ultimowow.com/?spell=53721 es un AoE (Area de Efecto) no lo puedes lanzar sobre ti mismo, por eso el @player no tiene efecto.

 

En 8/9/2026 a las 17:11, Djklyncan dijo:

#showtooltip Muerte y descomposición
/cast [@cursor] Muerte y descomposición

Aqui dos cosas:
1) La 3.3.5a no te permite lanzar con una macro un hechizo AoE, tienes q hacer click si o si en la zona.
2) El target @cursor no existe.